Mercurial > vim

view src/testdir/setup.vim @ 34664:af61243e5aeb

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
runtime(vim): Update base-syntax, match empty blob and :abclear modifiers (#14318) Commit: https://github.com/vim/vim/commit/982e191b38b493d148d73871a724381214e4c62f Author: dkearns <dougkearns@gmail.com> Date: Thu Mar 28 20:06:03 2024 +1100 runtime(vim): Update base-syntax, match empty blob and :abclear modifiers (https://github.com/vim/vim/issues/14318) - Match empty blob literals. - Match modifier arguments to :abclear commands. Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Thu, 28 Mar 2024 10:15:07 +0100
parents 695b50472e85
children 609bf5215823
line wrap: on
line source

" Common preparations for running tests.

" Only load this once.
if 1

  " When using xterm version 377 the response to the modifyOtherKeys status
  " interferes with some tests.  Remove the request from the t_TI termcap
  " entry.
  let &t_TI = substitute(&t_TI, "\<Esc>\\[?4m", '', '')

  if exists('s:did_load')
    finish
  endif
  let s:did_load = 1
endif

" Make sure 'runtimepath' and 'packpath' does not include $HOME.
set rtp=$VIM/vimfiles,$VIMRUNTIME,$VIM/vimfiles/after
if has('packages')
  let &packpath = &rtp
endif

" Only when the +eval feature is present.
if 1
  " Make sure the .Xauthority file can be found after changing $HOME.
  if $XAUTHORITY == ''
    let $XAUTHORITY = $HOME . '/.Xauthority'
  endif

  " Avoid storing shell history.
  let $HISTFILE = ""

  " Have current $HOME available as $ORIGHOME.  $HOME is used for option
  " defaults before we get here, and test_mksession checks that.
  let $ORIGHOME = $HOME

  " Make sure $HOME does not get read or written.
  " It must exist, gnome tries to create $HOME/.gnome2
  let $HOME = getcwd() . '/XfakeHOME'
  if !isdirectory($HOME)
    call mkdir($HOME)
  endif
endif