Mercurial > vim

view runtime/autoload/freebasic.vim @ 31359:adb96415b5b7 v9.0.1013

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1013: suspend test often fails on Mac OS Commit: https://github.com/vim/vim/commit/0a2f891adfc52d8f29733817fca15a1b642af1df Author: Bram Moolenaar <Bram@vim.org> Date: Mon Dec 5 21:21:46 2022 +0000 patch 9.0.1013: suspend test often fails on Mac OS Problem: Suspend test often fails on Mac OS. Solution: Make t_RP empty.
author Bram Moolenaar <Bram@vim.org>
date Mon, 05 Dec 2022 22:30:04 +0100
parents 912224cab37f
children
line wrap: on
line source

" Vim filetype plugin file
" Language:	FreeBASIC
" Maintainer:	Doug Kearns <dougkearns@gmail.com>
" Last Change:	2022 June 24

" Dialects can be one of fb, qb, fblite, or deprecated
" Precedence is forcelang > #lang > lang
function! freebasic#GetDialect() abort
  if exists("g:freebasic_forcelang")
    return g:freebasic_forcelang
  endif

  if exists("g:freebasic_lang")
    let dialect = g:freebasic_lang
  else
    let dialect = "fb"
  endif

  " override with #lang directive or metacommand

  let pat = '\c^\s*\%(#\s*lang\s\+\|''\s*$lang\s*:\s*\)"\([^"]*\)"'

  let save_cursor = getcurpos()
  call cursor(1, 1)
  let lnum = search(pat, 'cn')
  call setpos('.', save_cursor)

  if lnum
    let word = matchlist(getline(lnum), pat)[1]
    if word =~? '\<\%(fb\|deprecated\|fblite\|qb\)\>'
      let dialect = word
    else
      echomsg "freebasic#GetDialect: Invalid lang, found '" .. word .. "' at line " .. lnum .. " " .. getline(lnum)
    endif
  endif

  return dialect
endfunction

" vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker: