Mercurial > vim

view runtime/syntax/texinfo.vim @ 34082:a197265a2e07 v9.1.0010

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.1.0010: Keymap completion is not available Commit: https://github.com/vim/vim/commit/81642d9d6ff5cd6a90a012b1b98632ce51eeb1a8 Author: Doug Kearns <dougkearns@gmail.com> Date: Thu Jan 4 22:37:44 2024 +0100 patch 9.1.0010: Keymap completion is not available Problem: Keymap completion is not available Solution: Add keymap completion (Doug Kearns) Add keymap completion to the 'keymap' option, user commands and builtin completion functions. closes: #13692 Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Thu, 04 Jan 2024 22:45:04 +0100
parents 3a63b1e4a6f4
children
line wrap: on
line source

" Vim syntax file
" Language:         Texinfo (documentation format)
" Maintainer:       Robert Dodier <robert.dodier@gmail.com>
" Latest Revision:  2021-12-15

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match texinfoControlSequence display '\(@end [a-zA-Z@]\+\|@[a-zA-Z@]\+\)'

syn match texinfoComment         display '^\s*\(@comment\|@c\)\>.*$'

syn region texinfoCode matchgroup=texinfoControlSequence start="@code{" end="}" contains=ALL
syn region texinfoVerb matchgroup=texinfoControlSequence start="@verb{" end="}" contains=ALL

syn region texinfoArgument matchgroup=texinfoBrace start="{" end="}" contains=ALLBUT

syn region texinfoExample matchgroup=texinfoControlSequence start="^@example\s*$" end="^@end example\s*$" contains=ALL

syn region texinfoVerbatim matchgroup=texinfoControlSequence start="^@verbatim\s*$" end="^@end verbatim\s*$"

syn region texinfoMenu matchgroup=texinfoControlSequence start="^@menu\s*$" end="^@end menu\s*$"

if exists("g:texinfo_delimiters")
  syn match texinfoDelimiter display '[][{}]'
endif

hi def link texinfoDelimiter       Delimiter
hi def link texinfoComment         Comment
hi def link texinfoControlSequence Identifier
hi def link texinfoBrace           Operator
hi def link texinfoArgument        Special
hi def link texinfoExample         String
hi def link texinfoVerbatim        String
hi def link texinfoVerb            String
hi def link texinfoCode            String
hi def link texinfoMenu            String

let b:current_syntax = "texinfo"

let &cpo = s:cpo_save
unlet s:cpo_save