Mercurial > vim

view src/testdir/test_source.vim @ 19153:9efea787c3a6 v8.2.0136

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0136: stray ch_logfile() call Commit: https://github.com/vim/vim/commit/ed5adff1e6da412732514d82363005f85fe22e04 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Jan 20 21:32:51 2020 +0100 patch 8.2.0136: stray ch_logfile() call Problem: Stray ch_logfile() call. Solution: Remove it. (closes https://github.com/vim/vim/issues/5503)
author Bram Moolenaar <Bram@vim.org>
date Mon, 20 Jan 2020 21:45:04 +0100
parents ea3ac1de7704
children 02111977dd05
line wrap: on
line source

" Tests for the :source command.

func Test_source_autocmd()
  call writefile([
	\ 'let did_source = 1',
	\ ], 'Xsourced')
  au SourcePre *source* let did_source_pre = 1
  au SourcePost *source* let did_source_post = 1

  source Xsourced

  call assert_equal(g:did_source, 1)
  call assert_equal(g:did_source_pre, 1)
  call assert_equal(g:did_source_post, 1)

  call delete('Xsourced')
  au! SourcePre
  au! SourcePost
  unlet g:did_source
  unlet g:did_source_pre
  unlet g:did_source_post
endfunc

func Test_source_cmd()
  au SourceCmd *source* let did_source = expand('<afile>')
  au SourcePre *source* let did_source_pre = 2
  au SourcePost *source* let did_source_post = 2

  source Xsourced

  call assert_equal(g:did_source, 'Xsourced')
  call assert_false(exists('g:did_source_pre'))
  call assert_equal(g:did_source_post, 2)

  au! SourceCmd
  au! SourcePre
  au! SourcePost
endfunc

func Test_source_sandbox()
  new
  call writefile(["Ohello\<Esc>"], 'Xsourcehello')
  source! Xsourcehello | echo
  call assert_equal('hello', getline(1))
  call assert_fails('sandbox source! Xsourcehello', 'E48:')
  bwipe!
  call delete('Xsourcehello')
endfunc

" When deleting a file and immediately creating a new one the inode may be
" recycled.  Vim should not recognize it as the same script.
func Test_different_script()
  call writefile(['let s:var = "asdf"'], 'XoneScript')
  source XoneScript
  call delete('XoneScript')
  call writefile(['let g:var = s:var'], 'XtwoScript')
  call assert_fails('source XtwoScript', 'E121:')
  call delete('XtwoScript')
endfunc