Mercurial > vim

view src/testdir/test_tabline.vim @ 13533:9e9e9f10e311 v8.0.1640

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1640: Test_cwd() is flaky commit https://github.com/vim/vim/commit/65873846e088bb94028e9d591ea03e377cb206b5 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Mar 25 17:12:58 2018 +0200 patch 8.0.1640: Test_cwd() is flaky Problem: Test_cwd() is flaky. Solution: Add to list of flaky tests.
author Christian Brabandt <cb@256bit.org>
date Sun, 25 Mar 2018 17:15:06 +0200
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction