view runtime/indent/framescript.vim @ 16332:97e15f5b0082 v8.1.1171

patch 8.1.1171: statusline test could fail in large terminal commit https://github.com/vim/vim/commit/316c16797a0baee8f4bced2235b783b21fbbea65 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Apr 14 13:23:40 2019 +0200 patch 8.1.1171: statusline test could fail in large terminal Problem: Statusline test could fail in large terminal. Solution: Make the test work on a huge terminal. (Dominique Pelle, closes #4255)
author Bram Moolenaar <Bram@vim.org>
date Sun, 14 Apr 2019 13:30:04 +0200
parents d0a20101ecb2
children 9c221ad9634a
line wrap: on
line source

" Vim indent file
" Language:             FrameScript
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2008-07-19

if exists("b:did_indent")
  finish
endif
let b:did_indent = 1

setlocal indentexpr=GetFrameScriptIndent()
setlocal indentkeys=!^F,o,O,0=~Else,0=~EndIf,0=~EndLoop,0=~EndSub
setlocal nosmartindent

if exists("*GetFrameScriptIndent")
  finish
endif

function GetFrameScriptIndent()
  let lnum = prevnonblank(v:lnum - 1)

  if lnum == 0
    return 0
  endif

  if getline(v:lnum) =~ '^\s*\*'
    return cindent(v:lnum)
  endif

  let ind = indent(lnum)

  if getline(lnum) =~? '^\s*\%(If\|Loop\|Sub\)'
    let ind = ind + shiftwidth()
  endif

  if getline(v:lnum) =~? '^\s*\%(Else\|End\%(If\|Loop\|Sub\)\)'
    let ind = ind - shiftwidth()
  endif

  return ind
endfunction