Mercurial > vim

view runtime/syntax/group.vim @ 30154:9137d2bc93bf v9.0.0413

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.0413: ASAN reports a memory leak Commit: https://github.com/vim/vim/commit/b0d12e63e8c763ce940dc4c162111fedde2507ef Author: K.Takata <kentkt@csc.jp> Date: Thu Sep 8 10:55:38 2022 +0100 patch 9.0.0413: ASAN reports a memory leak Problem: ASAN reports a memory leak. Solution: Free the string received from the server. (Ken Takata, closes #11080)
author Bram Moolenaar <Bram@vim.org>
date Thu, 08 Sep 2022 12:00:05 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             group(5) user group file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2012-08-05

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   groupBegin          display '^' nextgroup=groupName

syn match   groupName           contained display '[^:]\+'
                                \ nextgroup=groupPasswordColon

syn match   groupPasswordColon  contained display ':'
                                \ nextgroup=groupPassword,groupShadow

syn match   groupPassword       contained display '[^:]*'
                                \ nextgroup=groupGIDColon

syn match   groupShadow         contained display '[x*]' nextgroup=groupGIDColon

syn match   groupGIDColon       contained display ':' nextgroup=groupGID

syn match   groupGID            contained display '\d*'
                                \ nextgroup=groupUserListColon

syn match   groupUserListColon  contained display ':' nextgroup=groupUserList

syn match   groupUserList       contained '[^,]\+'
                                \ nextgroup=groupUserListSep

syn match   groupUserListSep    contained display ',' nextgroup=groupUserList

hi def link groupDelimiter      Normal
hi def link groupName           Identifier
hi def link groupPasswordColon  groupDelimiter
hi def link groupPassword       Number
hi def link groupShadow         Special
hi def link groupGIDColon       groupDelimiter
hi def link groupGID            Number
hi def link groupUserListColon  groupDelimiter
hi def link groupUserList       Identifier
hi def link groupUserListSep    groupDelimiter

let b:current_syntax = "group"

let &cpo = s:cpo_save
unlet s:cpo_save