Mercurial > vim

view src/testdir/test_changelist.vim @ 25188:8998dff30044 v8.2.3130

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3130: Vim9: import test fails Commit: https://github.com/vim/vim/commit/b885a7c72c8fed5f14454633fb3ba9d77fff1c24 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jul 8 22:02:11 2021 +0200 patch 8.2.3130: Vim9: import test fails Problem: Vim9: import test fails. Solution: Rename directory back to "import", use "p" to avoid an error when the directory already exists.
author Bram Moolenaar <Bram@vim.org>
date Thu, 08 Jul 2021 22:15:03 +0200
parents 08940efa6b4e
children 255bc9a08e58
line wrap: on
line source

" Tests for the changelist functionality

source check.vim

" Tests for the getchangelist() function
func Test_getchangelist()
  CheckFeature jumplist

  bwipe!
  enew
  call assert_equal([], 10->getchangelist())
  call assert_equal([[], 0], getchangelist())

  call writefile(['line1', 'line2', 'line3'], 'Xfile1.txt')
  call writefile(['line1', 'line2', 'line3'], 'Xfile2.txt')

  edit Xfile1.txt
  exe "normal 1Goline\<C-G>u1.1"
  exe "normal 3Goline\<C-G>u2.1"
  exe "normal 5Goline\<C-G>u3.1"
  normal g;
  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 2],
	      \ getchangelist('%'))

  hide edit Xfile2.txt
  exe "normal 1GOline\<C-G>u1.0"
  exe "normal 2Goline\<C-G>u2.0"
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2],
	      \ getchangelist('%'))
  hide enew

  call assert_equal([[
	      \ {'lnum' : 2, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 4, 'col' : 4, 'coladd' : 0},
	      \ {'lnum' : 6, 'col' : 4, 'coladd' : 0}], 3], getchangelist(2))
  call assert_equal([[
	      \ {'lnum' : 1, 'col' : 6, 'coladd' : 0},
	      \ {'lnum' : 3, 'col' : 6, 'coladd' : 0}], 2], getchangelist(3))

  bwipe!
  call delete('Xfile1.txt')
  call delete('Xfile2.txt')
endfunc

" vim: shiftwidth=2 sts=2 expandtab