Mercurial > vim

view runtime/syntax/limits.vim @ 17399:859ac3df0b1f v8.1.1698

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1698: Appveyor build with MSVC fails commit https://github.com/vim/vim/commit/5d6844566a5dcb506c6d146f7e46f7e7d09220ae Author: Bram Moolenaar <Bram@vim.org> Date: Mon Jul 15 22:03:40 2019 +0200 patch 8.1.1698: Appveyor build with MSVC fails Problem: Appveyor build with MSVC fails. Solution: Remove the sed command
author Bram Moolenaar <Bram@vim.org>
date Mon, 15 Jul 2019 22:15:04 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             limits(5) configuration file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn keyword limitsTodo    contained TODO FIXME XXX NOTE

syn region  limitsComment display oneline start='^\s*#' end='$'
                          \ contains=limitsTodo,@Spell

syn match   limitsBegin   display '^'
                          \ nextgroup=limitsUser,limitsDefault,limitsComment
                          \ skipwhite

syn match   limitsUser    contained '[^ \t#*]\+'
                          \ nextgroup=limitsLimit,limitsDeLimit skipwhite

syn match   limitsDefault contained '*'
                          \ nextgroup=limitsLimit,limitsDeLimit skipwhite

syn match   limitsLimit   contained '[ACDFMNRSTUKLP]' nextgroup=limitsNumber
syn match   limitsDeLimit contained '-'

syn match   limitsNumber  contained '\d\+\>' nextgroup=limitsLimit skipwhite

hi def link limitsTodo    Todo
hi def link limitsComment Comment
hi def link limitsUser    Keyword
hi def link limitsDefault Macro
hi def link limitsLimit   Identifier
hi def link limitsDeLimit Special
hi def link limitsNumber  Number

let b:current_syntax = "limits"

let &cpo = s:cpo_save
unlet s:cpo_save