Mercurial > vim

view runtime/syntax/arch.vim @ 18116:7f57ea9a4ba8 v8.1.2053

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.2053: SafeStateAgain not triggered if callback uses feedkeys() Commit: https://github.com/vim/vim/commit/d103ee78432f9036d243b18dd5aac1263d3b7dc9 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Sep 18 21:15:31 2019 +0200 patch 8.1.2053: SafeStateAgain not triggered if callback uses feedkeys() Problem: SafeStateAgain not triggered if callback uses feedkeys(). Solution: Check for safe state in the input loop. Make log messages easier to find. Add 'S' flag to state().
author Bram Moolenaar <Bram@vim.org>
date Wed, 18 Sep 2019 21:30:03 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             GNU Arch inventory file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2007-06-17

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

setlocal iskeyword+=-

syn keyword archTodo    TODO FIXME XXX NOTE

syn region  archComment display start='^\%(#\|\s\)' end='$'
                        \ contains=archTodo,@Spell

syn match   archBegin   display '^' nextgroup=archKeyword,archComment

syn keyword archKeyword contained implicit tagline explicit names
syn keyword archKeyword contained untagged-source
                        \ nextgroup=archTMethod skipwhite
syn keyword archKeyword contained exclude junk backup precious unrecognized
                        \ source nextgroup=archRegex skipwhite

syn keyword archTMethod contained source precious backup junk unrecognized

syn match   archRegex   contained '\s*\zs.*'

hi def link archTodo    Todo
hi def link archComment Comment
hi def link archKeyword Keyword
hi def link archTMethod Type
hi def link archRegex   String

let b:current_syntax = "arch"

let &cpo = s:cpo_save
unlet s:cpo_save