Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 26731:7f4cc4e58f75 v8.2.3894

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3894: Vim9: no proper type check for first argument of call() Commit: https://github.com/vim/vim/commit/223d0a6bc8dc68039ceb6660de9576fafe178d73 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Dec 25 19:29:21 2021 +0000 patch 8.2.3894: Vim9: no proper type check for first argument of call() Problem: Vim9: no proper type check for first argument of call(). Solution: Add specific type check.
author Bram Moolenaar <Bram@vim.org>
date Sat, 25 Dec 2021 20:30:03 +0100
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab