view runtime/syntax/wsh.vim @ 28841:77a00aa3e215 v8.2.4944

patch 8.2.4944: text properties are wrong after "cc" Commit: https://github.com/vim/vim/commit/d0b1a09f44654bb5e29b09de1311845200f17d90 Author: LemonBoy <thatlemon@gmail.com> Date: Thu May 12 18:45:18 2022 +0100 patch 8.2.4944: text properties are wrong after "cc" Problem: Text properties are wrong after "cc". (Axel Forsman) Solution: Pass the deleted byte count to inserted_bytes(). (closes https://github.com/vim/vim/issues/10412, closes #7737, closes #5763)
author Bram Moolenaar <Bram@vim.org>
date Thu, 12 May 2022 20:00:02 +0200
parents a81bc802c17c
children
line wrap: on
line source

" Vim syntax file
" Language:	Windows Scripting Host
" Maintainer:	Paul Moore <pf_moore AT yahoo.co.uk>
" Last Change:	Fre, 24 Nov 2000 21:54:09 +0100

" This reuses the XML, VB and JavaScript syntax files. While VB is not
" VBScript, it's close enough for us. No attempt is made to handle
" other languages.
" Send comments, suggestions and requests to the maintainer.

" Quit when a syntax file was already loaded
if exists("b:current_syntax")
  finish
endif

let s:wsh_cpo_save = &cpo
set cpo&vim

runtime! syntax/xml.vim
unlet b:current_syntax

syn case ignore
syn include @wshVBScript <sfile>:p:h/vb.vim
unlet b:current_syntax
syn include @wshJavaScript <sfile>:p:h/javascript.vim
unlet b:current_syntax
syn region wshVBScript
    \ matchgroup=xmlTag    start="<script[^>]*VBScript\(>\|[^>]*[^/>]>\)"
    \ matchgroup=xmlEndTag end="</script>"
    \ fold
    \ contains=@wshVBScript
    \ keepend
syn region wshJavaScript
    \ matchgroup=xmlTag    start="<script[^>]*J\(ava\)\=Script\(>\|[^>]*[^/>]>\)"
    \ matchgroup=xmlEndTag end="</script>"
    \ fold
    \ contains=@wshJavaScript
    \ keepend

syn cluster xmlRegionHook add=wshVBScript,wshJavaScript

let b:current_syntax = "wsh"

let &cpo = s:wsh_cpo_save
unlet s:wsh_cpo_save