Mercurial > vim

view src/testdir/test_exists_autocmd.vim @ 32276:774c94489feb v9.0.1469

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1469: deferred functions not called from autocommands Commit: https://github.com/vim/vim/commit/960cf9119e3f4922ca9719feb5e0c0bc5e3b9840 Author: zeertzjq <zeertzjq@outlook.com> Date: Tue Apr 18 21:52:54 2023 +0100 patch 9.0.1469: deferred functions not called from autocommands Problem: Deferred functions not called from autocommands. Solution: Also go through the funccal_stack. (closes https://github.com/vim/vim/issues/12267)
author Bram Moolenaar <Bram@vim.org>
date Tue, 18 Apr 2023 23:00:03 +0200
parents 08940efa6b4e
children
line wrap: on
line source

" Test that groups and patterns are tested correctly when calling exists() for
" autocommands.

function Test_AutoCommands()
  let results=[]
  augroup auexists
  augroup END
  call assert_true(exists("##BufEnter"))
  call assert_false(exists("#BufEnter"))
  au BufEnter * let g:entered=1
  call assert_true(exists("#BufEnter"))
  call assert_false(exists("#auexists#BufEnter"))
  augroup auexists
  au BufEnter * let g:entered=1
  augroup END
  call assert_true(exists("#auexists#BufEnter"))
  call assert_false(exists("#BufEnter#*.test"))
  au BufEnter *.test let g:entered=1
  call assert_true(exists("#BufEnter#*.test"))
  edit testfile.test
  call assert_false(exists("#BufEnter#<buffer>"))
  au BufEnter <buffer> let g:entered=1
  call assert_true(exists("#BufEnter#<buffer>"))
  edit testfile2.test
  call assert_false(exists("#BufEnter#<buffer>"))
endfunction

" vim: shiftwidth=2 sts=2 expandtab