view runtime/ftplugin/typescriptreact.vim @ 32975:71cbad0921c9

runtime: Remove Brams name from a few more runtime files (#12780) Commit: https://github.com/vim/vim/commit/e8d6f03f6a61f60de6893253621d057f63dd6a23 Author: Christian Brabandt <cb@256bit.org> Date: Wed Aug 23 20:23:07 2023 +0100 runtime: Remove Brams name from a few more runtime files (https://github.com/vim/vim/issues/12780) syntax/model.vim: minor wording improvement Signed-off-by: Christian Brabandt <cb@256bit.org> Co-authored-by: Adri Verhoef <a3@a3.xs4all.nl>
author Christian Brabandt <cb@256bit.org>
date Thu, 24 Aug 2023 07:33:28 +0200
parents 0db0640e16e0
children
line wrap: on
line source

" Vim filetype plugin file
" Language:	TypeScript React
" Maintainer:	Doug Kearns <dougkearns@gmail.com>
" Last Change:	2020 Aug 09

let s:match_words = ""
let s:undo_ftplugin = ""

runtime! ftplugin/typescript.vim

let s:cpo_save = &cpo
set cpo-=C

if exists("b:match_words")
    let s:match_words = b:match_words
endif
if exists("b:undo_ftplugin")
    let s:undo_ftplugin = b:undo_ftplugin
endif

" Matchit configuration
if exists("loaded_matchit")
    let b:match_ignorecase = 0
    let b:match_words = s:match_words .
		\	'<:>,' .
		\	'<\@<=\([^ \t>/]\+\)\%(\s\+[^>]*\%([^/]>\|$\)\|>\|$\):<\@<=/\1>,' .
		\	'<\@<=\%([^ \t>/]\+\)\%(\s\+[^/>]*\|$\):/>'
endif

let b:undo_ftplugin = "unlet! b:match_words b:match_ignorecase | " . s:undo_ftplugin

let &cpo = s:cpo_save
unlet s:cpo_save