Mercurial > vim

view src/testdir/test_mksession_utf8.vim @ 33821:6c92d6f3a255 v9.0.2126

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.2126: unused assignments when checking 'listchars' Commit: https://github.com/vim/vim/commit/00624a2fa08d04bdded240d474e9cfdc193dbe10 Author: zeertzjq <zeertzjq@outlook.com> Date: Thu Nov 23 20:47:16 2023 +0100 patch 9.0.2126: unused assignments when checking 'listchars' Problem: Unused assignments when checking the value of 'listchars'. Solution: Loop only once when just checking the value. Add a test to check that this change doesn't cause double-free. closes: #13559 Signed-off-by: zeertzjq <zeertzjq@outlook.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Thu, 23 Nov 2023 21:00:04 +0100
parents 6990c1160ea5
children
line wrap: on
line source

" Test for :mksession, :mkview and :loadview in utf-8 encoding

set encoding=utf-8
scriptencoding utf-8

source check.vim
CheckFeature mksession

func Test_mksession_utf8()
  tabnew
  let wrap_save = &wrap
  set sessionoptions=buffers splitbelow fileencoding=utf-8
  call setline(1, [
    \   'start:',
    \   'no multibyte chAracter',
    \   '	one leaDing tab',
    \   '    four leadinG spaces',
    \   'two		consecutive tabs',
    \   'two	tabs	in one line',
    \   'one … multibyteCharacter',
    \   'a “b” two multiByte characters',
    \   '“c”1€ three mulTibyte characters'
    \ ])
  let tmpfile = tempname()
  exec 'w! ' . tmpfile
  /^start:
  set wrap
  vsplit
  norm! j16|
  split
  norm! j16|
  split
  norm! j16|
  split
  norm! j8|
  split
  norm! j8|
  split
  norm! j16|
  split
  norm! j16|
  split
  norm! j16|
  wincmd l

  set nowrap
  /^start:
  norm! j16|3zl
  split
  norm! j016|3zl
  split
  norm! j016|3zl
  split
  norm! j08|3zl
  split
  norm! j08|3zl
  split
  norm! j016|3zl
  split
  norm! j016|3zl
  split
  norm! j016|3zl
  split
  call wincol()
  mksession! test_mks.out
  let li = filter(readfile('test_mks.out'), 'v:val =~# "\\(^ *normal! 0\\|^ *exe ''normal!\\)"')
  let expected =<< trim [DATA]
    normal! 016|
    normal! 016|
    normal! 016|
    normal! 08|
    normal! 08|
    normal! 016|
    normal! 016|
    normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 8 . '|'
      normal! 08|
      exe 'normal! ' . s:c . '|zs' . 8 . '|'
      normal! 08|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
  [DATA]

  call assert_equal(expected, li)
  tabclose!

  call delete('test_mks.out')
  call delete(tmpfile)
  let &wrap = wrap_save
  set sessionoptions& splitbelow& fileencoding&
endfunc

" vim: shiftwidth=2 sts=2 expandtab