view src/testdir/test_fixeol.vim @ 19691:60b5abfc4897 v8.2.0402

patch 8.2.0402: setting local instead of global flag Commit: https://github.com/vim/vim/commit/30d53e2c11e670845830bdfc29bf8c1615df61a8 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Mar 18 21:10:44 2020 +0100 patch 8.2.0402: setting local instead of global flag Problem: Setting local instead of global flag. Solution: Prepend "g:" to "test_is_flaky".
author Bram Moolenaar <Bram@vim.org>
date Wed, 18 Mar 2020 21:15:03 +0100
parents 90aaa974594e
children 08940efa6b4e
line wrap: on
line source

" Tests for 'fixeol' and 'eol'
func Test_fixeol()
  " first write two test files – with and without trailing EOL
  " use Unix fileformat for consistency
  set ff=unix
  enew!
  call setline('.', 'with eol')
  w! XXEol
  enew!
  set noeol nofixeol
  call setline('.', 'without eol')
  w! XXNoEol
  set eol fixeol
  bwipe XXEol XXNoEol

  " try editing files with 'fixeol' disabled
  e! XXEol
  normal ostays eol
  set nofixeol
  w! XXTestEol
  e! XXNoEol
  normal ostays without
  set nofixeol
  w! XXTestNoEol
  bwipe! XXEol XXNoEol XXTestEol XXTestNoEol
  set fixeol

  " Append "END" to each file so that we can see what the last written char
  " was.
  normal ggdGaEND
  w >>XXEol
  w >>XXNoEol
  w >>XXTestEol
  w >>XXTestNoEol

  call assert_equal(['with eol', 'END'], readfile('XXEol'))
  call assert_equal(['without eolEND'], readfile('XXNoEol'))
  call assert_equal(['with eol', 'stays eol', 'END'], readfile('XXTestEol'))
  call assert_equal(['without eol', 'stays withoutEND'],
	      \ readfile('XXTestNoEol'))

  call delete('XXEol')
  call delete('XXNoEol')
  call delete('XXTestEol')
  call delete('XXTestNoEol')
  set ff& fixeol& eol&
  enew!
endfunc