Mercurial > vim

view src/testdir/test_tabline.vim @ 13724:5ef1e6170589 v8.0.1734

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1734: package directory not added to 'rtp' if prefix matches commit https://github.com/vim/vim/commit/f98a39ca57d001ba3e24831bae1e375790fb41f0 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Apr 18 22:18:23 2018 +0200 patch 8.0.1734: package directory not added to 'rtp' if prefix matches Problem: Package directory not added to 'rtp' if prefix matches. Solution: Check the match is a full match. (Ozaki Kiichi, closes https://github.com/vim/vim/issues/2817) Also handle different ways of spelling a path.
author Christian Brabandt <cb@256bit.org>
date Wed, 18 Apr 2018 22:30:07 +0200
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction