Mercurial > vim

view src/testdir/test_tabline.vim @ 12588:5bc07e5d2c1f v8.0.1172

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1172: when E734 is given option is still set commit https://github.com/vim/vim/commit/2a6a6c3014e728cd01c750b0f60484d4eaf22a8c Author: Bram Moolenaar <Bram@vim.org> Date: Mon Oct 2 19:29:48 2017 +0200 patch 8.0.1172: when E734 is given option is still set Problem: When E734 is given option is still set. Solution: Assign NULL to "s". (Christian Brabandt)
author Christian Brabandt <cb@256bit.org>
date Mon, 02 Oct 2017 19:30:04 +0200
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction