Mercurial > vim

view runtime/syntax/lyrics.vim @ 30791:574bf5c78a40 v9.0.0730

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.0730: startup test fails with right-left feature Commit: https://github.com/vim/vim/commit/9ce7915d0667e6cb8f930634473f0caf2967f4e3 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Oct 12 11:54:34 2022 +0100 patch 9.0.0730: startup test fails with right-left feature Problem: Startup test fails with right-left feature. Solution: Do not delete test file too early.
author Bram Moolenaar <Bram@vim.org>
date Wed, 12 Oct 2022 13:00:05 +0200
parents 0827d3d6d8c0
children 7b4f0a2a87bf
line wrap: on
line source

" Vim syntax file
" Language:     LyRiCs
" Maintainer:   ObserverOfTime <chronobserver@disroot.org>
" Filenames:    *.lrc
" Last Change:  2022 Sep 18

if exists('b:current_syntax')
    finish
endif

let s:cpo_save = &cpoptions
set cpoptions&vim

syn case ignore

" Errors
syn match lrcError /^.\+$/

" ID tags
syn match lrcTag /^\s*\[\a\+:.\+\]\s*$/ contains=lrcTagName,lrcTagValue
syn match lrcTagName contained nextgroup=lrcTagValue
            \ /\[\zs\(al\|ar\|au\|by\|encoding\|la\|id\|length\|offset\|re\|ti\|ve\)\ze:/
syn match lrcTagValue /:\zs.\+\ze\]/ contained

" Lyrics
syn match lrcLyricTime /^\s*\[\d\d:\d\d\.\d\d\]/
            \ contains=lrcNumber nextgroup=lrcLyricLine
syn match lrcLyricLine /.*$/ contained contains=lrcWordTime,@Spell
syn match lrcWordTime /<\d\d:\d\d\.\d\d>/ contained contains=lrcNumber,@NoSpell
syn match lrcNumber /[+-]\=\d\+/ contained

hi def link lrcLyricTime Label
hi def link lrcNumber Number
hi def link lrcTag PreProc
hi def link lrcTagName Identifier
hi def link lrcTagValue String
hi def link lrcWordTime Special
hi def link lrcError Error

let b:current_syntax = 'lyrics'

let &cpoptions = s:cpo_save
unlet s:cpo_save