patch 9.1.0265: console dialog cannot save unnamed buffers Commit: https://github.com/vim/vim/commit/df46115fc839c8912ed60646e86a412e5180ba1d Author: glepnir <glephunter@gmail.com> Date: Thu Apr 4 22:23:29 2024 +0200 patch 9.1.0265: console dialog cannot save unnamed buffers Problem: console dialog cannot save unnamed buffers Solution: set bufname before save (glepnir). Define dialog_con_gui to test for GUI+Console dialog support, use it to skip the test when the GUI feature has been defined. Note: The dialog_changed() function will also try to call the browse_save_fname() function, when FEAT_BROWSE is defined (which is only defined in a GUI build of Vim). This will eventually lead to a call of do_browse(), which causes an error message if a GUI is not currently running (see the TODO: in do_browse()) and will then lead to a failure in Test_goto_buf_with_onfirm(). Therefore, we must disable the Test_goto_buf_with_onfirm(), when the dialog_con_gui feature is enabled (which basically means dialog feature for GUI and Console builds, in contrast to the dialog_con and dialog_gui feature). (Previously this wasn't a problem, because the test aborted in the YES case for the :confirm :b XgotoConf case and did therefore not run into the browse function call) closes: #14398 Signed-off-by: glepnir <glephunter@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>

" Test for MzScheme interface and mzeval() function

source check.vim
CheckFeature mzscheme

func MzRequire()
  redir => l:mzversion
  mz (version)
  redir END
  if strpart(l:mzversion, 1, 1) < "4"
    " MzScheme versions < 4.x:
    mz (require (prefix vim- vimext))
  else
    " newer versions:
    mz (require (prefix-in vim- 'vimext))
    mz (require r5rs)
  endif
endfunc

func Test_mzscheme()
  new
  let lines =<< trim END
    1 line 1
    2 line 2
    3 line 3
  END
  call setline(1, lines)

  call MzRequire()
  mz (define l '("item0" "dictionary with list OK" "item2"))
  mz (define h (make-hash))
  mz (hash-set! h "list" l)

  call cursor(1, 1)
  " change buffer contents
  mz (vim-set-buff-line (vim-eval "line('.')") "1 changed line 1")
  call assert_equal('1 changed line 1', getline(1))

  " scalar test
  let tmp_string = mzeval('"string"')
  let tmp_1000 = '1000'->mzeval()
  call assert_equal('string1000', tmp_string .. tmp_1000)

  " dictionary containing a list
  call assert_equal('dictionary with list OK', mzeval("h")["list"][1])

  call cursor(2, 1)
  " circular list (at the same time test lists containing lists)
  mz (set-car! (cddr l) l)
  let l2 = mzeval("h")["list"]
  call assert_equal(l2[2], l2)

  " funcrefs
  mz (define vim:max (vim-eval "function('max')"))
  mz (define m (vim:max '(1 100 8)))
  let m = mzeval('m')
  call assert_equal(100, m)

  close!
endfunc

" vim: shiftwidth=2 sts=2 expandtab