Mercurial > vim

view runtime/syntax/netrc.vim @ 20705:5481c982a279 v8.2.0906

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0906: when setting 'termguicolors' SpellBad is no longer red Commit: https://github.com/vim/vim/commit/ea563cc22be043ff91dcbdf2878c3d1fd944e573 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Jun 5 19:36:57 2020 +0200 patch 8.2.0906: when setting 'termguicolors' SpellBad is no longer red Problem: When setting 'termguicolors' SpellBad is no longer red. Solution: Only use the RGB guisp color for cterm when using the "underline" or "undercurl" attributes to avoid the background color to be cleared. Also make t_8u empty when the termresponse indicates a real xterm. (closes #6207)
author Bram Moolenaar <Bram@vim.org>
date Fri, 05 Jun 2020 19:45:03 +0200
parents 1218c5353e2b
children b2e8663e6dcc
line wrap: on
line source

" Vim syntax file
" Language:             netrc(5) configuration file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2010-01-03

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn keyword netrcKeyword    machine nextgroup=netrcMachine skipwhite skipnl
syn keyword netrcKeyword    account
                          \ login
                          \ nextgroup=netrcLogin,netrcSpecial skipwhite skipnl
syn keyword netrcKeyword    password nextgroup=netrcPassword skipwhite skipnl
syn keyword netrcKeyword    default
syn keyword netrcKeyword    macdef
                          \ nextgroup=netrcInit,netrcMacroName skipwhite skipnl
syn region  netrcMacro      contained start='.' end='^$'

syn match   netrcMachine    contained display '\S\+'
syn match   netrcMachine    contained display '"[^\\"]*\(\\.[^\\"]*\)*"'
syn match   netrcLogin      contained display '\S\+'
syn match   netrcLogin      contained display '"[^\\"]*\(\\.[^\\"]*\)*"'
syn match   netrcPassword   contained display '\S\+'
syn match   netrcPassword   contained display '"[^\\"]*\(\\.[^\\"]*\)*"'
syn match   netrcMacroName  contained display '\S\+'
                          \ nextgroup=netrcMacro skipwhite skipnl
syn match   netrcMacroName  contained display '"[^\\"]*\(\\.[^\\"]*\)*"'
                          \ nextgroup=netrcMacro skipwhite skipnl

syn keyword netrcSpecial    contained anonymous
syn match   netrcInit       contained '\<init$'
                          \ nextgroup=netrcMacro skipwhite skipnl

syn sync fromstart

hi def link netrcKeyword    Keyword
hi def link netrcMacro      PreProc
hi def link netrcMachine    Identifier
hi def link netrcLogin      String
hi def link netrcPassword   String
hi def link netrcMacroName  String
hi def link netrcSpecial    Special
hi def link netrcInit       Special

let b:current_syntax = "netrc"

let &cpo = s:cpo_save
unlet s:cpo_save