Mercurial > vim

view runtime/syntax/gitattributes.vim @ 36258:4e190eb5f0ad draft

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
runtime(vim): Update base-syntax file, improve class, enum and interface highlighting Commit: https://github.com/vim/vim/commit/818c641b6fac73b574a2b760213f515cee9a3c8e Author: Doug Kearns <dougkearns@gmail.com> Date: Sun Oct 6 17:00:48 2024 +0200 runtime(vim): Update base-syntax file, improve class, enum and interface highlighting - Enable folding of class, enum and interface declarations. - Highlight constructor names with the Function highlight group, like other special methods. - Mark function definitions using special method names as errors. - Highlight :type arguments. fixes: #14393#issuecomment-2042796198. closes: #13810 Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Sun, 06 Oct 2024 17:15:04 +0200
parents fee9eccee266
children
line wrap: on
line source

" Vim syntax file
" Language:	git attributes
" Maintainer:	ObserverOfTime <chronobserver@disroot.org>
" Filenames:	.gitattributes, *.git/info/attributes
" Last Change:	2022 Sep 09

if exists('b:current_syntax')
    finish
endif

let s:cpo_save = &cpoptions
set cpoptions&vim

" Comment
syn keyword gitattributesTodo contained TODO FIXME XXX
syn match gitattributesComment /^\s*#.*/ contains=gitattributesTodo

" Pattern
syn match gitattributesPattern /^\s*#\@!\(".\+"\|\S\+\)/ skipwhite
            \ nextgroup=gitattributesAttrPrefixed,gitattributesAttrAssigned skipwhite
            \ contains=gitattributesGlob,gitattributesRange,gitattributesSeparator
syn match gitattributesGlob /\\\@1<![?*]/ contained
syn match gitattributesRange /\\\@1<!\[.\{-}\]/ contained
syn match gitattributesSeparator '/' contained

" Attribute
syn match gitattributesAttrPrefixed /[!-]\?[A-Za-z0-9_.][-A-Za-z0-9_.]*/
            \ transparent contained skipwhite
            \ nextgroup=gitattributesAttrPrefixed,gitattributesAttrAssigned
            \ contains=gitattributesPrefix,gitattributesName
syn match gitattributesAttrAssigned /[A-Za-z0-9_.][-A-Za-z0-9_.]*=\S\+/
            \ transparent contained skipwhite
            \ nextgroup=gitattributesAttrPrefixed,gitattributesAttrAssigned
            \ contains=gitattributesName,gitattributesAssign,gitattributesBoolean,gitattributesString
syn match gitattributesName /[A-Za-z0-9_.][-A-Za-z0-9_.]*/
            \ contained nextgroup=gitattributesAssign
syn match gitattributesPrefix /[!-]/ contained
            \ nextgroup=gitAttributesName
syn match gitattributesAssign '=' contained
            \ nextgroup=gitattributesBoolean,gitattributesString
syn match gitattributesString /=\@1<=\S\+/ contained
syn keyword gitattributesBoolean true false contained

" Macro
syn match gitattributesMacro /^\s*\[attr\]\s*\S\+/
            \ nextgroup=gitattributesAttribute skipwhite

hi def link gitattributesAssign Operator
hi def link gitattributesBoolean Boolean
hi def link gitattributesComment Comment
hi def link gitattributesGlob Special
hi def link gitattributesMacro Define
hi def link gitattributesName Identifier
hi def link gitattributesPrefix SpecialChar
hi def link gitattributesRange Special
hi def link gitattributesSeparator Delimiter
hi def link gitattributesString String
hi def link gitattributesTodo Todo

let b:current_syntax = 'gitattributes'

let &cpoptions = s:cpo_save
unlet s:cpo_save