Mercurial > vim

view runtime/ftplugin/mail.vim @ 12568:440d934bd616 v8.0.1162

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1162: shared script for tests cannot be included twice commit https://github.com/vim/vim/commit/660b85e39a48a9f2e3bd7e4d8b97d0a1b4842997 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Sep 30 14:26:58 2017 +0200 patch 8.0.1162: shared script for tests cannot be included twice Problem: Shared script for tests cannot be included twice. Solution: Include it where needed, it will "finish" if loaded again.
author Christian Brabandt <cb@256bit.org>
date Sat, 30 Sep 2017 14:30:05 +0200
parents fdb8a9c7bd91
children babd9f1dbe12
line wrap: on
line source

" Vim filetype plugin file
" Language:	Mail
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2012 Nov 20

" Only do this when not done yet for this buffer
if exists("b:did_ftplugin")
  finish
endif
let b:did_ftplugin = 1

let b:undo_ftplugin = "setl modeline< tw< fo< comments<"

" Don't use modelines in e-mail messages, avoid trojan horses and nasty
" "jokes" (e.g., setting 'textwidth' to 5).
setlocal nomodeline

" many people recommend keeping e-mail messages 72 chars wide
if &tw == 0
  setlocal tw=72
endif

" Set 'formatoptions' to break text lines and keep the comment leader ">".
setlocal fo+=tcql

" Add n:> to 'comments, in case it was removed elsewhere
setlocal comments+=n:>

" Add mappings, unless the user doesn't want this.
if !exists("no_plugin_maps") && !exists("no_mail_maps")
  " Quote text by inserting "> "
  if !hasmapto('<Plug>MailQuote')
    vmap <buffer> <LocalLeader>q <Plug>MailQuote
    nmap <buffer> <LocalLeader>q <Plug>MailQuote
  endif
  vnoremap <buffer> <Plug>MailQuote :s/^/> /<CR>:noh<CR>``
  nnoremap <buffer> <Plug>MailQuote :.,$s/^/> /<CR>:noh<CR>``
endif