Mercurial > vim

view runtime/syntax/protocols.vim @ 9752:429be545637a v7.4.2151

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/cf25fdb8f10a92b3bf9e295c466c1b69812b7886 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Aug 3 21:04:53 2016 +0200 patch 7.4.2151 Problem: Quickfix test fails on MS-Windows. Solution: Close the help window. (Christian Brabandt)
author Christian Brabandt <cb@256bit.org>
date Wed, 03 Aug 2016 21:15:05 +0200
parents 1f3b1021f002
children 1218c5353e2b
line wrap: on
line source

" Vim syntax file
" Language:         protocols(5) - Internet protocols definition file
" Maintainer:       Nikolai Weibull <now@bitwi.se>
" Latest Revision:  2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   protocolsBegin    display '^'
                              \ nextgroup=protocolsName,protocolsComment

syn match   protocolsName     contained display '[[:graph:]]\+'
                              \ nextgroup=protocolsPort skipwhite

syn match   protocolsPort     contained display '\d\+'
                              \ nextgroup=protocolsAliases,protocolsComment
                              \ skipwhite

syn match   protocolsAliases  contained display '\S\+'
                              \ nextgroup=protocolsAliases,protocolsComment
                              \ skipwhite

syn keyword protocolsTodo     contained TODO FIXME XXX NOTE

syn region  protocolsComment  display oneline start='#' end='$'
                              \ contains=protocolsTodo,@Spell

hi def link protocolsTodo      Todo
hi def link protocolsComment   Comment
hi def link protocolsName      Identifier
hi def link protocolsPort      Number
hi def link protocolsPPDiv     Delimiter
hi def link protocolsPPDivDepr Error
hi def link protocolsProtocol  Type
hi def link protocolsAliases   Macro

let b:current_syntax = "protocols"

let &cpo = s:cpo_save
unlet s:cpo_save