view src/testdir/test_tabline.vim @ 15290:424f2596f582 v8.1.0653

patch 8.1.0653: arglist test fails on MS-windows commit https://github.com/vim/vim/commit/3de8c2d1f027410db6a06f0fcd3355d96c8b8596 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Dec 28 19:29:35 2018 +0100 patch 8.1.0653: arglist test fails on MS-windows Problem: Arglist test fails on MS-windows. Solution: Only use a file name with a double quote on Unix.
author Bram Moolenaar <Bram@vim.org>
date Fri, 28 Dec 2018 19:30:06 +0100
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction