view src/testdir/test_undolevels.vim @ 7420:37092e334ef2 v7.4.1014

commit https://github.com/vim/vim/commit/06b0734d9cd2f39d4c12c7fd89a100eadbe5be78 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Dec 31 22:26:28 2015 +0100 patch 7.4.1014 Problem: fnamemodify('.', ':.') returns an empty string in Cygwin. Solution: Use CCP_RELATIVE in the call to cygwin_conv_path. (Jacob Niehus, closes https://github.com/vim/vim/issues/505)
author Christian Brabandt <cb@256bit.org>
date Thu, 31 Dec 2015 22:30:05 +0100
parents b5e9810b389d
children 17bbbca531be
line wrap: on
line source

" Tests for 'undolevels'

set nocompatible viminfo+=nviminfo

func FillBuffer()
  for i in range(1,13)
    put=i
    " Set 'undolevels' to split undo. 
    exe "setg ul=" . &g:ul
  endfor
endfunc

func Test_global_local_undolevels()
  new one
  set undolevels=5
  call FillBuffer()
  " will only undo the last 5 changes, end up with 13 - (5 + 1) = 7 lines
  earlier 10
  call assert_equal(5, &g:undolevels)
  call assert_equal(-123456, &l:undolevels)
  call assert_equal('7', getline('$'))

  new two
  setlocal undolevels=2
  call FillBuffer()
  " will only undo the last 2 changes, end up with 13 - (2 + 1) = 10 lines
  earlier 10
  call assert_equal(5, &g:undolevels)
  call assert_equal(2, &l:undolevels)
  call assert_equal('10', getline('$'))

  setlocal ul=10
  call assert_equal(5, &g:undolevels)
  call assert_equal(10, &l:undolevels)

  " Setting local value in "two" must not change local value in "one"
  wincmd p
  call assert_equal(5, &g:undolevels)
  call assert_equal(-123456, &l:undolevels)

  new three
  setglobal ul=50
  call assert_equal(50, &g:undolevels)
  call assert_equal(-123456, &l:undolevels)

endfunc