Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 12777:3272e1cde1eb v8.0.1266

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1266: Test_swap_directory was commented out commit https://github.com/vim/vim/commit/ffe010fa0363d1a04b15cc6af119a4af63ba9363 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Nov 4 22:30:40 2017 +0100 patch 8.0.1266: Test_swap_directory was commented out Problem: Test_swap_directory was accidentally commented out. Solution: Uncomment the test.
author Christian Brabandt <cb@256bit.org>
date Sat, 04 Nov 2017 22:45:05 +0100
parents 18cda18a38e2
children 08940efa6b4e
line wrap: on
line source

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')