Mercurial > vim

view runtime/syntax/manconf.vim @ 33646:314ef6fe82e8 v9.0.2063

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.2063: pacman hooks are detected as conf filetype Commit: https://github.com/vim/vim/commit/7d254dbc2db35badc65668db85f826f605486986 Author: Guido Cella <guido@guidocella.xyz> Date: Mon Oct 23 19:27:06 2023 +0200 patch 9.0.2063: pacman hooks are detected as conf filetype Problem: pacman hooks are detected as conf filetype Solution: make it consistent to pacman.conf and detect those hooks as confini Because confini has much better syntax highlighting than conf. For reference, I identified pacman.conf and pacman hooks as dosini in https://github.com/vim/vim/pull/6335, then https://github.com/vim/vim/pull/10213 changed them to conf, then https://github.com/vim/vim/pull/10518 changed pacman.conf to confini but forgot to change hooks. closes: #13399 Signed-off-by: Christian Brabandt <cb@256bit.org> Co-authored-by: Guido Cella <guido@guidocella.xyz>
author Christian Brabandt <cb@256bit.org>
date Mon, 23 Oct 2023 19:30:09 +0200
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             man.conf(5) - man configuration file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn keyword manconfTodo         contained TODO FIXME XXX NOTE

syn region  manconfComment      display oneline start='^#' end='$'
                                \ contains=manconfTodo,@Spell

if !has("win32") && $OSTYPE =~   'bsd'
  syn match   manconfBegin      display '^'
                                \ nextgroup=manconfKeyword,manconfSection,
                                \ manconfComment skipwhite

  syn keyword manconfKeyword    contained _build _crunch
                                \ nextgroup=manconfExtCmd skipwhite

  syn keyword manconfKeyword    contained _suffix
                                \ nextgroup=manconfExt skipwhite

  syn keyword manconfKeyword    contained _crunch

  syn keyword manconfKeyword    contained _subdir _version _whatdb
                                \ nextgroup=manconfPaths skipwhite

  syn match   manconfExtCmd     contained display '\.\S\+'
                                \ nextgroup=manconfPaths skipwhite

  syn match   manconfSection    contained '[^#_ \t]\S*'
                                \ nextgroup=manconfPaths skipwhite

  syn keyword manconfSection    contained _default
                                \ nextgroup=manconfPaths skipwhite

  syn match   manconfPaths      contained display '\S\+'
                                \ nextgroup=manconfPaths skipwhite

  syn match   manconfExt        contained display '\.\S\+'

  hi def link manconfExtCmd     Type
  hi def link manconfSection    Identifier
  hi def link manconfPaths      String
else
  syn match   manconfBegin      display '^'
                                \ nextgroup=manconfBoolean,manconfKeyword,
                                \ manconfDecompress,manconfComment skipwhite

  syn keyword manconfBoolean    contained FSSTND FHS NOAUTOPATH NOCACHE

  syn keyword manconfKeyword    contained MANBIN
                                \ nextgroup=manconfPath skipwhite

  syn keyword manconfKeyword    contained MANPATH MANPATH_MAP
                                \ nextgroup=manconfFirstPath skipwhite

  syn keyword manconfKeyword    contained APROPOS WHATIS TROFF NROFF JNROFF EQN
                                \ NEQN JNEQN TBL COL REFER PIC VGRIND GRAP
                                \ PAGER BROWSER HTMLPAGER CMP CAT COMPRESS
                                \ DECOMPRESS MANDEFOPTIONS
                                \ nextgroup=manconfCommand skipwhite

  syn keyword manconfKeyword    contained COMPRESS_EXT
                                \ nextgroup=manconfExt skipwhite

  syn keyword manconfKeyword    contained MANSECT
                                \ nextgroup=manconfManSect skipwhite

  syn match   manconfPath       contained display '\S\+'

  syn match   manconfFirstPath  contained display '\S\+'
                                \ nextgroup=manconfSecondPath skipwhite

  syn match   manconfSecondPath contained display '\S\+'

  syn match   manconfCommand    contained display '\%(/[^/ \t]\+\)\+'
                                \ nextgroup=manconfCommandOpt skipwhite

  syn match   manconfCommandOpt contained display '\S\+'
                                \ nextgroup=manconfCommandOpt skipwhite

  syn match   manconfExt        contained display '\.\S\+'

  syn match   manconfManSect    contained '[^:]\+' nextgroup=manconfManSectSep

  syn match   manconfManSectSep contained ':' nextgroup=manconfManSect

  syn match   manconfDecompress contained '\.\S\+'
                                \ nextgroup=manconfCommand skipwhite

  hi def link manconfBoolean    Boolean
  hi def link manconfPath       String
  hi def link manconfFirstPath  manconfPath
  hi def link manconfSecondPath manconfPath
  hi def link manconfCommand    String
  hi def link manconfCommandOpt Special
  hi def link manconfManSect    Identifier
  hi def link manconfManSectSep Delimiter
  hi def link manconfDecompress Type
endif

hi def link manconfTodo         Todo
hi def link manconfComment      Comment
hi def link manconfKeyword      Keyword
hi def link manconfExt          Type

let b:current_syntax = "manconf"

let &cpo = s:cpo_save
unlet s:cpo_save