Mercurial > vim

view src/testdir/test_source.vim @ 19141:2c7d60b1bfa9 v8.2.0130

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0130: Python3 ranges are not tested Commit: https://github.com/vim/vim/commit/904edabb64422467bf79f48f3a6305e0eddeea94 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Jan 19 13:57:54 2020 +0100 patch 8.2.0130: Python3 ranges are not tested Problem: Python3 ranges are not tested. Solution: Add test. (Dominique Pelle, closes https://github.com/vim/vim/issues/5498)
author Bram Moolenaar <Bram@vim.org>
date Sun, 19 Jan 2020 14:00:04 +0100
parents 8d91579414b8
children ea3ac1de7704
line wrap: on
line source

" Tests for the :source command.

func Test_source_autocmd()
  call writefile([
	\ 'let did_source = 1',
	\ ], 'Xsourced')
  au SourcePre *source* let did_source_pre = 1
  au SourcePost *source* let did_source_post = 1

  source Xsourced

  call assert_equal(g:did_source, 1)
  call assert_equal(g:did_source_pre, 1)
  call assert_equal(g:did_source_post, 1)

  call delete('Xsourced')
  au! SourcePre
  au! SourcePost
  unlet g:did_source
  unlet g:did_source_pre
  unlet g:did_source_post
endfunc

func Test_source_cmd()
  au SourceCmd *source* let did_source = expand('<afile>')
  au SourcePre *source* let did_source_pre = 2
  au SourcePost *source* let did_source_post = 2

  source Xsourced

  call assert_equal(g:did_source, 'Xsourced')
  call assert_false(exists('g:did_source_pre'))
  call assert_equal(g:did_source_post, 2)

  au! SourceCmd
  au! SourcePre
  au! SourcePost
endfunc

func Test_source_sandbox()
  new
  call writefile(["Ohello\<Esc>"], 'Xsourcehello')
  source! Xsourcehello | echo
  call assert_equal('hello', getline(1))
  call assert_fails('sandbox source! Xsourcehello', 'E48:')
  bwipe!
  call delete('Xsourcehello')
endfunc