Mercurial > vim

view runtime/indent/rnoweb.vim @ 27269:24da57a079ef v8.2.4163

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.4163: no error for omitting function name after autoload prefix Commit: https://github.com/vim/vim/commit/2017d6f3b1d523204e5471e941cfa687b4da0058 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jan 20 19:38:46 2022 +0000 patch 8.2.4163: no error for omitting function name after autoload prefix Problem: No error for omitting function name after autoload prefix. Solution: Check for missing function name. (issue https://github.com/vim/vim/issues/9577)
author Bram Moolenaar <Bram@vim.org>
date Thu, 20 Jan 2022 20:45:04 +0100
parents 0ecb909e3249
children b2412874362f
line wrap: on
line source

" Vim indent file
" Language:	Rnoweb
" Author:	Jakson Alves de Aquino <jalvesaq@gmail.com>
" Homepage:     https://github.com/jalvesaq/R-Vim-runtime
" Last Change:	Fri Apr 15, 2016  10:58PM


" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
runtime indent/tex.vim

function! s:NoTeXIndent()
  return indent(line("."))
endfunction

if &indentexpr == "" || &indentexpr == "GetRnowebIndent()"
  let s:TeXIndent = function("s:NoTeXIndent")
else
  let s:TeXIndent = function(substitute(&indentexpr, "()", "", ""))
endif

unlet! b:did_indent
runtime indent/r.vim
let s:RIndent = function(substitute(&indentexpr, "()", "", ""))
let b:did_indent = 1

setlocal indentkeys=0{,0},!^F,o,O,e,},=\bibitem,=\item
setlocal indentexpr=GetRnowebIndent()

if exists("*GetRnowebIndent")
  finish
endif

function GetRnowebIndent()
  let curline = getline(".")
  if curline =~ '^<<.*>>=$' || curline =~ '^\s*@$'
    return 0
  endif
  if search("^<<", "bncW") > search("^@", "bncW")
    return s:RIndent()
  endif
  return s:TeXIndent()
endfunction

" vim: sw=2