Mercurial > vim

view runtime/syntax/services.vim @ 23160:19575087e859 v8.2.2126

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.2126: Ruby: missing function prototype Commit: https://github.com/vim/vim/commit/0e12140550a63bb1e45771edb89b941959440cfe Author: Bram Moolenaar <Bram@vim.org> Date: Thu Dec 10 20:50:34 2020 +0100 patch 8.2.2126: Ruby: missing function prototype Problem: Ruby: missing function prototype. Solution: Add the prototype.
author Bram Moolenaar <Bram@vim.org>
date Thu, 10 Dec 2020 21:00:04 +0100
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save