Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 15251:17525ca95e1e v8.1.0634

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0634: text properties cannot cross line boundaries commit https://github.com/vim/vim/commit/e3d31b02a56710e64ef0c1eb6ac5afcc57cb4890 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Dec 24 23:07:04 2018 +0100 patch 8.1.0634: text properties cannot cross line boundaries Problem: Text properties cannot cross line boundaries. Solution: Support multi-line text properties.
author Bram Moolenaar <Bram@vim.org>
date Mon, 24 Dec 2018 23:15:05 +0100
parents 18cda18a38e2
children 08940efa6b4e
line wrap: on
line source

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')