Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 28103:1615d305c71d v8.2.4576

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.4576: Vim9: error for comparing with null can be annoying Commit: https://github.com/vim/vim/commit/056678184f679c2989b73bd48eda112f3c79a62f Author: Bram Moolenaar <Bram@vim.org> Date: Tue Mar 15 20:21:33 2022 +0000 patch 8.2.4576: Vim9: error for comparing with null can be annoying Problem: Vim9: error for comparing with null can be annoying. Solution: Allow comparing anything with null. (closes https://github.com/vim/vim/issues/9948)
author Bram Moolenaar <Bram@vim.org>
date Tue, 15 Mar 2022 21:30:03 +0100
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab