Mercurial > vim

view src/testdir/test_changedtick.vim @ 11469:0ade9dd85156 v8.0.0618

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0618: NFA regex engine handles [0-z] incorrectly commit https://github.com/vim/vim/commit/bb7943b7920ef2f88cb9b6f46c34c7946c370819 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Jun 5 13:30:06 2017 +0200 patch 8.0.0618: NFA regex engine handles [0-z] incorrectly Problem: NFA regex engine handles [0-z] incorrectly. Solution: Return at the right point. (James McCoy, closes https://github.com/vim/vim/issues/1703)
author Christian Brabandt <cb@256bit.org>
date Mon, 05 Jun 2017 13:45:04 +0200
parents fd1760f8c215
children 1f418d27e11f
line wrap: on
line source

" Tests for b:changedtick

func Test_changedtick_increments()
  new
  " New buffer has an empty line, tick starts at 2.
  let expected = 2
  call assert_equal(expected, b:changedtick)
  call assert_equal(expected, b:['changedtick'])
  call setline(1, 'hello')
  let expected += 1
  call assert_equal(expected, b:changedtick)
  call assert_equal(expected, b:['changedtick'])
  undo
  " Somehow undo counts as two changes.
  let expected += 2
  call assert_equal(expected, b:changedtick)
  call assert_equal(expected, b:['changedtick'])
  bwipe!
endfunc

func Test_changedtick_dict_entry()
  let d = b:
  call assert_equal(b:changedtick, d['changedtick'])
endfunc

func Test_changedtick_bdel()
  new
  let bnr = bufnr('%')
  let v = b:changedtick
  bdel
  " Delete counts as a change too.
  call assert_equal(v + 1, getbufvar(bnr, 'changedtick'))
endfunc

func Test_changedtick_islocked()
  call assert_equal(0, islocked('b:changedtick'))
  let d = b:
  call assert_equal(0, islocked('d.changedtick'))
endfunc

func Test_changedtick_fixed()
  call assert_fails('let b:changedtick = 4', 'E46:')
  call assert_fails('let b:["changedtick"] = 4', 'E46:')

  call assert_fails('lockvar b:changedtick', 'E940:')
  call assert_fails('lockvar b:["changedtick"]', 'E46:')
  call assert_fails('unlockvar b:changedtick', 'E940:')
  call assert_fails('unlockvar b:["changedtick"]', 'E46:')
  call assert_fails('unlet b:changedtick', 'E795:')
  call assert_fails('unlet b:["changedtick"]', 'E46:')

  let d = b:
  call assert_fails('lockvar d["changedtick"]', 'E46:')
  call assert_fails('unlockvar d["changedtick"]', 'E46:')
  call assert_fails('unlet d["changedtick"]', 'E46:')

endfunc