patch 9.0.2065: EXPAND flag set for filetype option Commit: https://github.com/vim/vim/commit/3932072ab435eb171ab55b2a2c0185358cd0d7bf Author: Doug Kearns <dougkearns@gmail.com> Date: Wed Oct 25 20:54:00 2023 +0200 patch 9.0.2065: EXPAND flag set for filetype option Problem: EXPAND flag set for filetype option Solution: Remove P_EXPAND flag from the 'filetype' option Remove P_EXPAND flag from the 'filetype' option Problem: P_EXPAND flag is erroneously set for 'filetype' option Solution: Remove the P_EXPAND flag This flag is used by string options that accept file path values. See :help set_env. This appears to have been included in d5e8c92 and resulted from an incorrect implementation of 'filetype' completion. See #12900 for a small discussion. related: #12900 closes: #13416 Signed-off-by: Christian Brabandt <cb@256bit.org> Co-authored-by: Doug Kearns <dougkearns@gmail.com>

" Vim indent file
" Language:		FrameScript
" Maintainer:		Doug Kearns <dougkearns@gmail.com>
" Previous Maintainer:	Nikolai Weibull <now@bitwi.se>
" Last Change:		24 Sep 2021

if exists("b:did_indent")
  finish
endif
let b:did_indent = 1

setlocal indentexpr=GetFrameScriptIndent()
setlocal indentkeys=!^F,o,O,0=~Else,0=~EndIf,0=~EndLoop,0=~EndSub
setlocal nosmartindent

let b:undo_indent = "setl inde< indk< si<"

if exists("*GetFrameScriptIndent")
  finish
endif

function GetFrameScriptIndent()
  let lnum = prevnonblank(v:lnum - 1)

  if lnum == 0
    return 0
  endif

  if getline(v:lnum) =~ '^\s*\*'
    return cindent(v:lnum)
  endif

  let ind = indent(lnum)

  if getline(lnum) =~? '^\s*\%(If\|Loop\|Sub\)'
    let ind = ind + shiftwidth()
  endif

  if getline(v:lnum) =~? '^\s*\%(Else\|End\%(If\|Loop\|Sub\)\)'
    let ind = ind - shiftwidth()
  endif

  return ind
endfunction