Mercurial > vim

view src/testdir/test_tabline.vim @ 10557:018b7ecc58db v8.0.0168

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0168: not all float functionality is tested commit https://github.com/vim/vim/commit/872004132f25cabe59352912889e042d6c7e6b4e Author: Bram Moolenaar <Bram@vim.org> Date: Tue Jan 10 16:31:20 2017 +0100 patch 8.0.0168: not all float functionality is tested Problem: Still some float functionality is not covered by tests. Solution: Add more tests. (Dominique Pelle, closes https://github.com/vim/vim/issues/1364)
author Christian Brabandt <cb@256bit.org>
date Tue, 10 Jan 2017 16:45:04 +0100
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction